#include <Arduino.h>
#include <ESP8266WiFi.h>
#include <WiFiClient.h>
#include <ESP8266WebServer.h>
#include <ESP8266mDNS.h>
#include <html.h>
#include <Graph.h>
#include <Sensor.h>

const char *ssid = "NodeMCU";

ESP8266WebServer server(80);


Sensor accelerometer = Sensor();

Graph graphAcc = Graph(200, 50);

void handleAccelerometer()
{   
    int16_t bias = 0;
    const int arr_size = 10000;
    char *html_code = new char[arr_size];
    memset(html_code,  '\0', sizeof(char)*arr_size);

    bias += getHtml(HTML_BEGIN, *html_code, arr_size, 0);
    bias += getHtml(STYLE, *html_code, arr_size, bias);
    bias += getHtml(SCRIPT_BEGIN, *html_code, arr_size, bias);
    for (int i = 0; i != graphAcc.graphSize - 1; i++) {
        bias += snprintf((html_code+bias), arr_size - bias, "context.lineTo(%i*2, %i);\n", i, graphAcc.graphArray[i]);
    }
    bias += getHtml(SCRIPT_END, *html_code, arr_size, bias);
    //bias += snprintf((html_code+bias), arr_size - bias, "<br />Current accelerometer: %i", acc);
    bias += getHtml(HTML_END, *html_code, arr_size, bias);

    server.send(200, "text/html", html_code);

    delete[] html_code;
}

void updateAccelerometer()
{
    if ((millis() - accelerometer.lastUpdate) > (1000 / graphAcc.graphUpdateRate))
    {
        accelerometer.lastValue = map(analogRead(A0), 512, 768, 200, 0);
        if (graphAcc.graphCounter < graphAcc.graphSize - 1) {
            graphAcc.graphArray[graphAcc.graphCounter] = accelerometer.lastValue;
            graphAcc.graphCounter++;
        } else {  
            for(int i = 0; i != graphAcc.graphCounter; i++) {
                graphAcc.graphArray[i] = graphAcc.graphArray[i + 1];
            }       
            graphAcc.graphArray[graphAcc.graphCounter] = accelerometer.lastValue;   
        }
        accelerometer.lastUpdate = millis();
    }
}

void handleNotFound()
{
    String message = "File Not Found\n\n";
    message += "URI: ";
    message += server.uri();
    message += "\nMethod: ";
    message += (server.method() == HTTP_GET) ? "GET" : "POST";
    message += "\nArguments: ";
    message += server.args();
    message += "\n";
    for (uint8_t i = 0; i < server.args(); i++)
    {
        message += " " + server.argName(i) + ": " + server.arg(i) + "\n";
    }
    server.send(404, "text/plain", message);
}

void setup(void)
{
    pinMode(A0, INPUT);
    Serial.begin(115200);	
    WiFi.softAP(ssid);

	IPAddress myIP = WiFi.softAPIP();
	Serial.print("AP IP address: ");
	Serial.println(myIP);
    
    server.on("/accelerometer", handleAccelerometer);
    server.on("/", []() {
        server.send(200, "text/plain", "http://192.168.4.1/accelerometer");
    });
    server.onNotFound(handleNotFound);

    server.begin();
    Serial.println("HTTP server started");
}

void loop(void)
{   
    updateAccelerometer();
    server.handleClient();
}